list.v 177 KB
Newer Older
1
(* Copyright (c) 2012-2019, Coq-std++ developers. *)
2 3 4
(* This file is distributed under the terms of the BSD license. *)
(** This file collects general purpose definitions and theorems on lists that
are not in the Coq standard library. *)
5
From Coq Require Export Permutation.
6
From stdpp Require Export numbers base option.
7
Set Default Proof Using "Type*".
Robbert Krebbers's avatar
Robbert Krebbers committed
8

9 10 11
Arguments length {_} _ : assert.
Arguments cons {_} _ _ : assert.
Arguments app {_} _ _ : assert.
12

13 14 15
Instance: Params (@length) 1 := {}.
Instance: Params (@cons) 1 := {}.
Instance: Params (@app) 1 := {}.
Robbert Krebbers's avatar
Robbert Krebbers committed
16

17 18 19
Notation tail := tl.
Notation take := firstn.
Notation drop := skipn.
20

21
Arguments head {_} _ : assert.
22 23 24
Arguments tail {_} _ : assert.
Arguments take {_} !_ !_ / : assert.
Arguments drop {_} !_ !_ / : assert.
25

26
Instance: Params (@head) 1 := {}.
27 28 29
Instance: Params (@tail) 1 := {}.
Instance: Params (@take) 1 := {}.
Instance: Params (@drop) 1 := {}.
30

31 32
Arguments Permutation {_} _ _ : assert.
Arguments Forall_cons {_} _ _ _ _ _ : assert.
33
Remove Hints Permutation_cons : typeclass_instances.
34

35 36 37 38 39 40
Notation "(::)" := cons (only parsing) : list_scope.
Notation "( x ::)" := (cons x) (only parsing) : list_scope.
Notation "(:: l )" := (λ x, cons x l) (only parsing) : list_scope.
Notation "(++)" := app (only parsing) : list_scope.
Notation "( l ++)" := (app l) (only parsing) : list_scope.
Notation "(++ k )" := (λ l, app l k) (only parsing) : list_scope.
41 42 43 44 45 46 47 48 49

Infix "≡ₚ" := Permutation (at level 70, no associativity) : stdpp_scope.
Notation "(≡ₚ)" := Permutation (only parsing) : stdpp_scope.
Notation "( x ≡ₚ)" := (Permutation x) (only parsing) : stdpp_scope.
Notation "(≡ₚ x )" := (λ y, y ≡ₚ x) (only parsing) : stdpp_scope.
Notation "(≢ₚ)" := (λ x y, ¬x ≡ₚ y) (only parsing) : stdpp_scope.
Notation "x ≢ₚ y":= (¬x ≡ₚ y) (at level 70, no associativity) : stdpp_scope.
Notation "( x ≢ₚ)" := (λ y, x ≢ₚ y) (only parsing) : stdpp_scope.
Notation "(≢ₚ x )" := (λ y, y ≢ₚ x) (only parsing) : stdpp_scope.
50

Robbert Krebbers's avatar
Robbert Krebbers committed
51 52 53 54
Infix "≡ₚ@{ A }" :=
  (@Permutation A) (at level 70, no associativity, only parsing) : stdpp_scope.
Notation "(≡ₚ@{ A } )" := (@Permutation A) (only parsing) : stdpp_scope.

Robbert Krebbers's avatar
Robbert Krebbers committed
55 56 57
Instance maybe_cons {A} : Maybe2 (@cons A) := λ l,
  match l with x :: l => Some (x,l) | _ => None end.

58
(** * Definitions *)
59 60 61 62 63 64
(** Setoid equality lifted to lists *)
Inductive list_equiv `{Equiv A} : Equiv (list A) :=
  | nil_equiv : [] ≡ []
  | cons_equiv x y l k : x ≡ y → l ≡ k → x :: l ≡ y :: k.
Existing Instance list_equiv.

65 66
(** The operation [l !! i] gives the [i]th element of the list [l], or [None]
in case [i] is out of bounds. *)
67 68
Instance list_lookup {A} : Lookup nat A (list A) :=
  fix go i l {struct l} : option A := let _ : Lookup _ _ _ := @go in
69
  match l with
70
  | [] => None | x :: l => match i with 0 => Some x | S i => l !! i end
71
  end.
72 73 74

(** The operation [alter f i l] applies the function [f] to the [i]th element
of [l]. In case [i] is out of bounds, the list is returned unchanged. *)
75
Instance list_alter {A} : Alter nat A (list A) := λ f,
76
  fix go i l {struct l} :=
77 78
  match l with
  | [] => []
79
  | x :: l => match i with 0 => f x :: l | S i => x :: go i l end
80
  end.
81

82 83
(** The operation [<[i:=x]> l] overwrites the element at position [i] with the
value [x]. In case [i] is out of bounds, the list is returned unchanged. *)
84 85
Instance list_insert {A} : Insert nat A (list A) :=
  fix go i y l {struct l} := let _ : Insert _ _ _ := @go in
86 87 88 89
  match l with
  | [] => []
  | x :: l => match i with 0 => y :: l | S i => x :: <[i:=y]>l end
  end.
90 91 92 93 94
Fixpoint list_inserts {A} (i : nat) (k l : list A) : list A :=
  match k with
  | [] => l
  | y :: k => <[i:=y]>(list_inserts (S i) k l)
  end.
95
Instance: Params (@list_inserts) 1 := {}.
96

97 98 99
(** The operation [delete i l] removes the [i]th element of [l] and moves
all consecutive elements one position ahead. In case [i] is out of bounds,
the list is returned unchanged. *)
100 101
Instance list_delete {A} : Delete nat (list A) :=
  fix go (i : nat) (l : list A) {struct l} : list A :=
102 103
  match l with
  | [] => []
104
  | x :: l => match i with 0 => l | S i => x :: @delete _ _ go i l end
105
  end.
106 107 108

(** The function [option_list o] converts an element [Some x] into the
singleton list [[x]], and [None] into the empty list [[]]. *)
Robbert Krebbers's avatar
Robbert Krebbers committed
109
Definition option_list {A} : option A → list A := option_rect _ (λ x, [x]) [].
110
Instance: Params (@option_list) 1 := {}.
111
Instance maybe_list_singleton {A} : Maybe (λ x : A, [x]) := λ l,
112
  match l with [x] => Some x | _ => None end.
Robbert Krebbers's avatar
Robbert Krebbers committed
113 114 115 116

(** The function [filter P l] returns the list of elements of [l] that
satisfies [P]. The order remains unchanged. *)
Instance list_filter {A} : Filter A (list A) :=
117
  fix go P _ l := let _ : Filter _ _ := @go in
Robbert Krebbers's avatar
Robbert Krebbers committed
118 119
  match l with
  | [] => []
120
  | x :: l => if decide (P x) then x :: filter P l else filter P l
121 122 123 124
  end.

(** The function [list_find P l] returns the first index [i] whose element
satisfies the predicate [P]. *)
125
Definition list_find {A} P `{∀ x, Decision (P x)} : list A → option (nat * A) :=
126 127
  fix go l :=
  match l with
128 129
  | [] => None
  | x :: l => if decide (P x) then Some (0,x) else prod_map S id <$> go l
130
  end.
131
Instance: Params (@list_find) 3 := {}.
Robbert Krebbers's avatar
Robbert Krebbers committed
132 133 134 135

(** The function [replicate n x] generates a list with length [n] of elements
with value [x]. *)
Fixpoint replicate {A} (n : nat) (x : A) : list A :=
136
  match n with 0 => [] | S n => x :: replicate n x end.
137
Instance: Params (@replicate) 2 := {}.
Robbert Krebbers's avatar
Robbert Krebbers committed
138 139 140

(** The function [reverse l] returns the elements of [l] in reverse order. *)
Definition reverse {A} (l : list A) : list A := rev_append l [].
141
Instance: Params (@reverse) 1 := {}.
Robbert Krebbers's avatar
Robbert Krebbers committed
142

143 144 145 146
(** The function [last l] returns the last element of the list [l], or [None]
if the list [l] is empty. *)
Fixpoint last {A} (l : list A) : option A :=
  match l with [] => None | [x] => Some x | _ :: l => last l end.
147
Instance: Params (@last) 1 := {}.
148

Robbert Krebbers's avatar
Robbert Krebbers committed
149 150 151 152 153 154
(** The function [resize n y l] takes the first [n] elements of [l] in case
[length l ≤ n], and otherwise appends elements with value [x] to [l] to obtain
a list of length [n]. *)
Fixpoint resize {A} (n : nat) (y : A) (l : list A) : list A :=
  match l with
  | [] => replicate n y
155
  | x :: l => match n with 0 => [] | S n => x :: resize n y l end
Robbert Krebbers's avatar
Robbert Krebbers committed
156
  end.
157
Arguments resize {_} !_ _ !_ : assert.
158
Instance: Params (@resize) 2 := {}.
Robbert Krebbers's avatar
Robbert Krebbers committed
159

160 161 162
(** The function [reshape k l] transforms [l] into a list of lists whose sizes
are specified by [k]. In case [l] is too short, the resulting list will be
padded with empty lists. In case [l] is too long, it will be truncated. *)
163 164
Fixpoint reshape {A} (szs : list nat) (l : list A) : list (list A) :=
  match szs with
165
  | [] => [] | sz :: szs => take sz l :: reshape szs (drop sz l)
166
  end.
167
Instance: Params (@reshape) 2 := {}.
168

169
Definition sublist_lookup {A} (i n : nat) (l : list A) : option (list A) :=
170 171 172 173
  guard (i + n ≤ length l); Some (take n (drop i l)).
Definition sublist_alter {A} (f : list A → list A)
    (i n : nat) (l : list A) : list A :=
  take i l ++ f (take n (drop i l)) ++ drop (i + n) l.
174

175 176 177 178
(** Functions to fold over a list. We redefine [foldl] with the arguments in
the same order as in Haskell. *)
Notation foldr := fold_right.
Definition foldl {A B} (f : A → B → A) : A → list B → A :=
179
  fix go a l := match l with [] => a | x :: l => go (f a x) l end.
180 181 182

(** The monadic operations. *)
Instance list_ret: MRet list := λ A x, x :: @nil A.
183 184
Instance list_fmap : FMap list := λ A B f,
  fix go (l : list A) := match l with [] => [] | x :: l => f x :: go l end.
185 186 187 188 189 190
Instance list_omap : OMap list := λ A B f,
  fix go (l : list A) :=
  match l with
  | [] => []
  | x :: l => match f x with Some y => y :: go l | None => go l end
  end.
191 192
Instance list_bind : MBind list := λ A B f,
  fix go (l : list A) := match l with [] => [] | x :: l => f x ++ go l end.
193 194
Instance list_join: MJoin list :=
  fix go A (ls : list (list A)) : list A :=
195
  match ls with [] => [] | l :: ls => l ++ @mjoin _ go _ ls end.
196
Definition mapM `{MBind M, MRet M} {A B} (f : A → M B) : list A → M (list B) :=
197
  fix go l :=
198
  match l with [] => mret [] | x :: l => y ← f x; k ← go l; mret (y :: k) end.
199 200 201

(** We define stronger variants of map and fold that allow the mapped
function to use the index of the elements. *)
Robbert Krebbers's avatar
Robbert Krebbers committed
202 203 204 205 206
Fixpoint imap {A B} (f : nat → A → B) (l : list A) : list B :=
  match l with
  | [] => []
  | x :: l => f 0 x :: imap (f ∘ S) l
  end.
207

208
Definition zipped_map {A B} (f : list A → list A → A → B) :
Robbert Krebbers's avatar
Robbert Krebbers committed
209 210 211 212 213
    list A → list A → list B := fix go l k :=
  match k with
  | [] => []
  | x :: k => f l k x :: go (x :: l) k
  end.
214

Robbert Krebbers's avatar
Robbert Krebbers committed
215
Fixpoint imap2 {A B C} (f : nat → A → B → C) (l : list A) (k : list B) : list C :=
Robbert Krebbers's avatar
Robbert Krebbers committed
216
  match l, k with
Robbert Krebbers's avatar
Robbert Krebbers committed
217 218
  | [], _ | _, [] => []
  | x :: l, y :: k => f 0 x y :: imap2 (f ∘ S) l k
Robbert Krebbers's avatar
Robbert Krebbers committed
219 220
  end.

221 222 223 224 225
Inductive zipped_Forall {A} (P : list A → list A → A → Prop) :
    list A → list A → Prop :=
  | zipped_Forall_nil l : zipped_Forall P l []
  | zipped_Forall_cons l k x :
     P l k x → zipped_Forall P (x :: l) k → zipped_Forall P l (x :: k).
226 227
Arguments zipped_Forall_nil {_ _} _ : assert.
Arguments zipped_Forall_cons {_ _} _ _ _ _ _ : assert.
228

229 230 231 232 233 234 235
(** The function [mask f βs l] applies the function [f] to elements in [l] at
positions that are [true] in [βs]. *)
Fixpoint mask {A} (f : A → A) (βs : list bool) (l : list A) : list A :=
  match βs, l with
  | β :: βs, x :: l => (if β then f x else x) :: mask f βs l
  | _, _ => l
  end.
236 237 238 239

(** The function [permutations l] yields all permutations of [l]. *)
Fixpoint interleave {A} (x : A) (l : list A) : list (list A) :=
  match l with
240
  | [] => [[x]]| y :: l => (x :: y :: l) :: ((y ::) <$> interleave x l)
241 242
  end.
Fixpoint permutations {A} (l : list A) : list (list A) :=
243
  match l with [] => [[]] | x :: l => permutations l ≫= interleave x end.
244

Robbert Krebbers's avatar
Robbert Krebbers committed
245 246 247 248
(** The predicate [suffix] holds if the first list is a suffix of the second.
The predicate [prefix] holds if the first list is a prefix of the second. *)
Definition suffix {A} : relation (list A) := λ l1 l2, ∃ k, l2 = k ++ l1.
Definition prefix {A} : relation (list A) := λ l1 l2, ∃ k, l2 = l1 ++ k.
249 250
Infix "`suffix_of`" := suffix (at level 70) : stdpp_scope.
Infix "`prefix_of`" := prefix (at level 70) : stdpp_scope.
Tej Chajed's avatar
Tej Chajed committed
251 252
Hint Extern 0 (_ `prefix_of` _) => reflexivity : core.
Hint Extern 0 (_ `suffix_of` _) => reflexivity : core.
Robbert Krebbers's avatar
Robbert Krebbers committed
253

254
Section prefix_suffix_ops.
255 256
  Context `{EqDecision A}.

Robbert Krebbers's avatar
Robbert Krebbers committed
257
  Definition max_prefix : list A → list A → list A * list A * list A :=
258 259 260 261 262
    fix go l1 l2 :=
    match l1, l2 with
    | [], l2 => ([], l2, [])
    | l1, [] => (l1, [], [])
    | x1 :: l1, x2 :: l2 =>
263
      if decide_rel (=) x1 x2
264
      then prod_map id (x1 ::) (go l1 l2) else (x1 :: l1, x2 :: l2, [])
265
    end.
Robbert Krebbers's avatar
Robbert Krebbers committed
266 267
  Definition max_suffix (l1 l2 : list A) : list A * list A * list A :=
    match max_prefix (reverse l1) (reverse l2) with
268 269
    | (k1, k2, k3) => (reverse k1, reverse k2, reverse k3)
    end.
Robbert Krebbers's avatar
Robbert Krebbers committed
270 271
  Definition strip_prefix (l1 l2 : list A) := (max_prefix l1 l2).1.2.
  Definition strip_suffix (l1 l2 : list A) := (max_suffix l1 l2).1.2.
272
End prefix_suffix_ops.
Robbert Krebbers's avatar
Robbert Krebbers committed
273

274
(** A list [l1] is a sublist of [l2] if [l2] is obtained by removing elements
275 276 277
from [l1] without changing the order. *)
Inductive sublist {A} : relation (list A) :=
  | sublist_nil : sublist [] []
278
  | sublist_skip x l1 l2 : sublist l1 l2 → sublist (x :: l1) (x :: l2)
279
  | sublist_cons x l1 l2 : sublist l1 l2 → sublist l1 (x :: l2).
280
Infix "`sublist_of`" := sublist (at level 70) : stdpp_scope.
Tej Chajed's avatar
Tej Chajed committed
281
Hint Extern 0 (_ `sublist_of` _) => reflexivity : core.
282

Robbert Krebbers's avatar
Robbert Krebbers committed
283
(** A list [l2] submseteq a list [l1] if [l2] is obtained by removing elements
284
from [l1] while possiblity changing the order. *)
Robbert Krebbers's avatar
Robbert Krebbers committed
285 286 287 288 289 290
Inductive submseteq {A} : relation (list A) :=
  | submseteq_nil : submseteq [] []
  | submseteq_skip x l1 l2 : submseteq l1 l2 → submseteq (x :: l1) (x :: l2)
  | submseteq_swap x y l : submseteq (y :: x :: l) (x :: y :: l)
  | submseteq_cons x l1 l2 : submseteq l1 l2 → submseteq l1 (x :: l2)
  | submseteq_trans l1 l2 l3 : submseteq l1 l2 → submseteq l2 l3 → submseteq l1 l3.
291
Infix "⊆+" := submseteq (at level 70) : stdpp_scope.
Tej Chajed's avatar
Tej Chajed committed
292
Hint Extern 0 (_ ⊆+ _) => reflexivity : core.
293

294 295 296 297 298 299 300 301 302 303 304 305 306 307
(** Removes [x] from the list [l]. The function returns a [Some] when the
+removal succeeds and [None] when [x] is not in [l]. *)
Fixpoint list_remove `{EqDecision A} (x : A) (l : list A) : option (list A) :=
  match l with
  | [] => None
  | y :: l => if decide (x = y) then Some l else (y ::) <$> list_remove x l
  end.

(** Removes all elements in the list [k] from the list [l]. The function returns
a [Some] when the removal succeeds and [None] some element of [k] is not in [l]. *)
Fixpoint list_remove_list `{EqDecision A} (k : list A) (l : list A) : option (list A) :=
  match k with
  | [] => Some l | x :: k => list_remove x l ≫= list_remove_list k
  end.
308

309 310 311 312 313
Inductive Forall3 {A B C} (P : A → B → C → Prop) :
     list A → list B → list C → Prop :=
  | Forall3_nil : Forall3 P [] [] []
  | Forall3_cons x y z l k k' :
     P x y z → Forall3 P l k k' → Forall3 P (x :: l) (y :: k) (z :: k').
314

315 316
(** Set operations on lists *)
Instance list_subseteq {A} : SubsetEq (list A) := λ l1 l2, ∀ x, x ∈ l1 → x ∈ l2.
317

318
Section list_set.
319
  Context `{dec : EqDecision A}.
Robbert Krebbers's avatar
Robbert Krebbers committed
320
  Global Instance elem_of_list_dec : RelDecision (∈@{list A}).
321 322
  Proof.
   refine (
323
    fix go x l :=
324 325
    match l return Decision (x ∈ l) with
    | [] => right _
326
    | y :: l => cast_if_or (decide (x = y)) (go x l)
327 328 329 330 331 332 333 334 335 336 337 338 339
    end); clear go dec; subst; try (by constructor); abstract by inversion 1.
  Defined.
  Fixpoint remove_dups (l : list A) : list A :=
    match l with
    | [] => []
    | x :: l =>
      if decide_rel (∈) x l then remove_dups l else x :: remove_dups l
    end.
  Fixpoint list_difference (l k : list A) : list A :=
    match l with
    | [] => []
    | x :: l =>
      if decide_rel (∈) x k
340
      then list_difference l k else x :: list_difference l k
341
    end.
342
  Definition list_union (l k : list A) : list A := list_difference l k ++ k.
343 344 345 346 347
  Fixpoint list_intersection (l k : list A) : list A :=
    match l with
    | [] => []
    | x :: l =>
      if decide_rel (∈) x k
348
      then x :: list_intersection l k else list_intersection l k
349 350 351 352 353 354 355 356 357
    end.
  Definition list_intersection_with (f : A → A → option A) :
    list A → list A → list A := fix go l k :=
    match l with
    | [] => []
    | x :: l => foldr (λ y,
        match f x y with None => id | Some z => (z ::) end) (go l k) k
    end.
End list_set.
358

359 360 361 362
(** These next functions allow to efficiently encode lists of positives (bit
strings) into a single positive and go in the other direction as well. This is
for example used for the countable instance of lists and in namespaces.
 The main functions are [positives_flatten] and [positives_unflatten]. *)
363 364 365 366 367 368
Fixpoint positives_flatten_go (xs : list positive) (acc : positive) : positive :=
  match xs with
  | [] => acc
  | x :: xs => positives_flatten_go xs (acc~1~0 ++ Preverse (Pdup x))
  end.

369 370 371 372 373 374 375
(** Flatten a list of positives into a single positive by duplicating the bits
of each element, so that:

- [0 -> 00]
- [1 -> 11]

and then separating each element with [10]. *)
376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392
Definition positives_flatten (xs : list positive) : positive :=
  positives_flatten_go xs 1.

Fixpoint positives_unflatten_go
        (p : positive)
        (acc_xs : list positive)
        (acc_elm : positive)
  : option (list positive) :=
  match p with
  | 1 => Some acc_xs
  | p'~0~0 => positives_unflatten_go p' acc_xs (acc_elm~0)
  | p'~1~1 => positives_unflatten_go p' acc_xs (acc_elm~1)
  | p'~1~0 => positives_unflatten_go p' (acc_elm :: acc_xs) 1
  | _ => None
  end%positive.

(** Unflatten a positive into a list of positives, assuming the encoding
393
used by [positives_flatten]. *)
394 395 396
Definition positives_unflatten (p : positive) : option (list positive) :=
  positives_unflatten_go p [] 1.

397
(** * Basic tactics on lists *)
Robbert Krebbers's avatar
Robbert Krebbers committed
398
(** The tactic [discriminate_list] discharges a goal if it submseteq
399 400
a list equality involving [(::)] and [(++)] of two lists that have a different
length as one of its hypotheses. *)
401
Tactic Notation "discriminate_list" hyp(H) :=
402
  apply (f_equal length) in H;
403
  repeat (csimpl in H || rewrite app_length in H); exfalso; lia.
404
Tactic Notation "discriminate_list" :=
405
  match goal with H : _ =@{list _} _ |- _ => discriminate_list H end.
406

407
(** The tactic [simplify_list_eq] simplifies hypotheses involving
408 409
equalities on lists using injectivity of [(::)] and [(++)]. Also, it simplifies
lookups in singleton lists. *)
410
Lemma app_inj_1 {A} (l1 k1 l2 k2 : list A) :
411 412
  length l1 = length k1 → l1 ++ l2 = k1 ++ k2 → l1 = k1 ∧ l2 = k2.
Proof. revert k1. induction l1; intros [|??]; naive_solver. Qed.
413
Lemma app_inj_2 {A} (l1 k1 l2 k2 : list A) :
414 415
  length l2 = length k2 → l1 ++ l2 = k1 ++ k2 → l1 = k1 ∧ l2 = k2.
Proof.
416
  intros ? Hl. apply app_inj_1; auto.
417 418
  apply (f_equal length) in Hl. rewrite !app_length in Hl. lia.
Qed.
419
Ltac simplify_list_eq :=
420
  repeat match goal with
421
  | _ => progress simplify_eq/=
422
  | H : _ ++ _ = _ ++ _ |- _ => first
423
    [ apply app_inv_head in H | apply app_inv_tail in H
424 425
    | apply app_inj_1 in H; [destruct H|done]
    | apply app_inj_2 in H; [destruct H|done] ]
Robbert Krebbers's avatar
Robbert Krebbers committed
426
  | H : [?x] !! ?i = Some ?y |- _ =>
427
    destruct i; [change (Some x = Some y) in H | discriminate]
428
  end.
429

430 431
(** * General theorems *)
Section general_properties.
Robbert Krebbers's avatar
Robbert Krebbers committed
432
Context {A : Type}.
433 434
Implicit Types x y z : A.
Implicit Types l k : list A.
Robbert Krebbers's avatar
Robbert Krebbers committed
435

436
Global Instance: Inj2 (=) (=) (=) (@cons A).
437
Proof. by injection 1. Qed.
438
Global Instance: ∀ k, Inj (=) (=) (k ++).
439
Proof. intros ???. apply app_inv_head. Qed.
440
Global Instance: ∀ k, Inj (=) (=) (++ k).
441
Proof. intros ???. apply app_inv_tail. Qed.
442
Global Instance: Assoc (=) (@app A).
443 444 445 446 447
Proof. intros ???. apply app_assoc. Qed.
Global Instance: LeftId (=) [] (@app A).
Proof. done. Qed.
Global Instance: RightId (=) [] (@app A).
Proof. intro. apply app_nil_r. Qed.
448

449
Lemma app_nil l1 l2 : l1 ++ l2 = [] ↔ l1 = [] ∧ l2 = [].
450
Proof. split. apply app_eq_nil. by intros [-> ->]. Qed.
451 452
Lemma app_singleton l1 l2 x :
  l1 ++ l2 = [x] ↔ l1 = [] ∧ l2 = [x] ∨ l1 = [x] ∧ l2 = [].
453
Proof. split. apply app_eq_unit. by intros [[-> ->]|[-> ->]]. Qed.
454 455 456
Lemma cons_middle x l1 l2 : l1 ++ x :: l2 = l1 ++ [x] ++ l2.
Proof. done. Qed.
Lemma list_eq l1 l2 : (∀ i, l1 !! i = l2 !! i) → l1 = l2.
457
Proof.
458
  revert l2. induction l1 as [|x l1 IH]; intros [|y l2] H.
459 460 461
  - done.
  - discriminate (H 0).
  - discriminate (H 0).
462
  - f_equal; [by injection (H 0)|]. apply (IH _ $ λ i, H (S i)).
463
Qed.
464 465
Global Instance list_eq_dec {dec : EqDecision A} : EqDecision (list A) :=
  list_eq_dec dec.
466 467 468
Global Instance list_eq_nil_dec l : Decision (l = []).
Proof. by refine match l with [] => left _ | _ => right _ end. Defined.
Lemma list_singleton_reflect l :
469
  option_reflect (λ x, l = [x]) (length l ≠ 1) (maybe (λ x, [x]) l).
470 471 472 473
Proof. by destruct l as [|? []]; constructor. Defined.

Definition nil_length : length (@nil A) = 0 := eq_refl.
Definition cons_length x l : length (x :: l) = S (length l) := eq_refl.
474
Lemma nil_or_length_pos l : l = [] ∨ length l ≠ 0.
475
Proof. destruct l; simpl; auto with lia. Qed.
476
Lemma nil_length_inv l : length l = 0 → l = [].
477 478
Proof. by destruct l. Qed.
Lemma lookup_nil i : @nil A !! i = None.
479
Proof. by destruct i. Qed.
480
Lemma lookup_tail l i : tail l !! i = l !! S i.
481
Proof. by destruct l. Qed.
482
Lemma lookup_lt_Some l i x : l !! i = Some x → i < length l.
483
Proof. revert i. induction l; intros [|?] ?; naive_solver auto with arith. Qed.
484 485 486
Lemma lookup_lt_is_Some_1 l i : is_Some (l !! i) → i < length l.
Proof. intros [??]; eauto using lookup_lt_Some. Qed.
Lemma lookup_lt_is_Some_2 l i : i < length l → is_Some (l !! i).
487
Proof. revert i. induction l; intros [|?] ?; naive_solver eauto with lia. Qed.
488 489 490 491 492 493 494 495
Lemma lookup_lt_is_Some l i : is_Some (l !! i) ↔ i < length l.
Proof. split; auto using lookup_lt_is_Some_1, lookup_lt_is_Some_2. Qed.
Lemma lookup_ge_None l i : l !! i = None ↔ length l ≤ i.
Proof. rewrite eq_None_not_Some, lookup_lt_is_Some. lia. Qed.
Lemma lookup_ge_None_1 l i : l !! i = None → length l ≤ i.
Proof. by rewrite lookup_ge_None. Qed.
Lemma lookup_ge_None_2 l i : length l ≤ i → l !! i = None.
Proof. by rewrite lookup_ge_None. Qed.
496 497 498
Lemma list_eq_same_length l1 l2 n :
  length l2 = n → length l1 = n →
  (∀ i x y, i < n → l1 !! i = Some x → l2 !! i = Some y → x = y) → l1 = l2.
Robbert Krebbers's avatar
Robbert Krebbers committed
499
Proof.
500
  intros <- Hlen Hl; apply list_eq; intros i. destruct (l2 !! i) as [x|] eqn:Hx.
501
  - destruct (lookup_lt_is_Some_2 l1 i) as [y Hy].
502 503
    { rewrite Hlen; eauto using lookup_lt_Some. }
    rewrite Hy; f_equal; apply (Hl i); eauto using lookup_lt_Some.
504
  - by rewrite lookup_ge_None, Hlen, <-lookup_ge_None.
Robbert Krebbers's avatar
Robbert Krebbers committed
505
Qed.
506
Lemma lookup_app_l l1 l2 i : i < length l1 → (l1 ++ l2) !! i = l1 !! i.
507
Proof. revert i. induction l1; intros [|?]; naive_solver auto with lia. Qed.
508 509
Lemma lookup_app_l_Some l1 l2 i x : l1 !! i = Some x → (l1 ++ l2) !! i = Some x.
Proof. intros. rewrite lookup_app_l; eauto using lookup_lt_Some. Qed.
510
Lemma lookup_app_r l1 l2 i :
511
  length l1 ≤ i → (l1 ++ l2) !! i = l2 !! (i - length l1).
512 513 514 515 516 517
Proof. revert i. induction l1; intros [|?]; simpl; auto with lia. Qed.
Lemma lookup_app_Some l1 l2 i x :
  (l1 ++ l2) !! i = Some x ↔
    l1 !! i = Some x ∨ length l1 ≤ i ∧ l2 !! (i - length l1) = Some x.
Proof.
  split.
518
  - revert i. induction l1 as [|y l1 IH]; intros [|i] ?;
519
      simplify_eq/=; auto with lia.
520
    destruct (IH i) as [?|[??]]; auto with lia.
521
  - intros [?|[??]]; auto using lookup_app_l_Some. by rewrite lookup_app_r.
522
Qed.
523 524 525
Lemma list_lookup_middle l1 l2 x n :
  n = length l1 → (l1 ++ x :: l2) !! n = Some x.
Proof. intros ->. by induction l1. Qed.
526

527
Lemma nth_lookup l i d : nth i l d = default d (l !! i).
528 529 530 531
Proof. revert i. induction l as [|x l IH]; intros [|i]; simpl; auto. Qed.
Lemma nth_lookup_Some l i d x : l !! i = Some x → nth i l d = x.
Proof. rewrite nth_lookup. by intros ->. Qed.
Lemma nth_lookup_or_length l i d : {l !! i = Some (nth i l d)} + {length l ≤ i}.
Ralf Jung's avatar
Ralf Jung committed
532
Proof.
533
  rewrite nth_lookup. destruct (l !! i) eqn:?; eauto using lookup_ge_None_1.
Ralf Jung's avatar
Ralf Jung committed
534 535
Qed.

536
Lemma list_insert_alter l i x : <[i:=x]>l = alter (λ _, x) i l.
537
Proof. by revert i; induction l; intros []; intros; f_equal/=. Qed.
538
Lemma alter_length f l i : length (alter f i l) = length l.
539
Proof. revert i. by induction l; intros [|?]; f_equal/=. Qed.
540
Lemma insert_length l i x : length (<[i:=x]>l) = length l.
541
Proof. revert i. by induction l; intros [|?]; f_equal/=. Qed.
542
Lemma list_lookup_alter f l i : alter f i l !! i = f <$> l !! i.
543
Proof. revert i. induction l. done. intros [|i]. done. apply (IHl i). Qed.
Robbert Krebbers's avatar
Robbert Krebbers committed
544
Lemma list_lookup_alter_ne f l i j : i ≠ j → alter f i l !! j = l !! j.
545
Proof. revert i j. induction l; [done|]. intros [] []; naive_solver. Qed.
546
Lemma list_lookup_insert l i x : i < length l → <[i:=x]>l !! i = Some x.
547
Proof. revert i. induction l; intros [|?] ?; f_equal/=; auto with lia. Qed.
548
Lemma list_lookup_insert_ne l i j x : i ≠ j → <[i:=x]>l !! j = l !! j.
549
Proof. revert i j. induction l; [done|]. intros [] []; naive_solver. Qed.
550 551 552 553 554 555
Lemma list_lookup_insert_Some l i x j y :
  <[i:=x]>l !! j = Some y ↔
    i = j ∧ x = y ∧ j < length l ∨ i ≠ j ∧ l !! j = Some y.
Proof.
  destruct (decide (i = j)) as [->|];
    [split|rewrite list_lookup_insert_ne by done; tauto].
556
  - intros Hy. assert (j < length l).
557 558
    { rewrite <-(insert_length l j x); eauto using lookup_lt_Some. }
    rewrite list_lookup_insert in Hy by done; naive_solver.
559
  - intros [(?&?&?)|[??]]; rewrite ?list_lookup_insert; naive_solver.
560 561 562
Qed.
Lemma list_insert_commute l i j x y :
  i ≠ j → <[i:=x]>(<[j:=y]>l) = <[j:=y]>(<[i:=x]>l).
563
Proof. revert i j. by induction l; intros [|?] [|?] ?; f_equal/=; auto. Qed.
Robbert Krebbers's avatar
Robbert Krebbers committed
564 565
Lemma list_insert_id l i x : l !! i = Some x → <[i:=x]>l = l.
Proof. revert i. induction l; intros [|i] [=]; f_equal/=; auto. Qed.
566 567
Lemma list_insert_ge l i x : length l ≤ i → <[i:=x]>l = l.
Proof. revert i. induction l; intros [|i] ?; f_equal/=; auto with lia. Qed.
Michael Sammler's avatar
Michael Sammler committed
568 569 570
Lemma list_insert_insert l i x y :
  <[i:=x]> (<[i:=y]> l) = <[i:=x]> l.
Proof. revert i. induction l; intros [|i]; f_equal/=; auto. Qed.
Robbert Krebbers's avatar
Robbert Krebbers committed
571

572 573
Lemma list_lookup_other l i x :
  length l ≠ 1 → l !! i = Some x → ∃ j y, j ≠ i ∧ l !! j = Some y.
Robbert Krebbers's avatar
Robbert Krebbers committed
574
Proof.
575
  intros. destruct i, l as [|x0 [|x1 l]]; simplify_eq/=.
576 577
  - by exists 1, x1.
  - by exists 0, x0.
Robbert Krebbers's avatar
Robbert Krebbers committed
578
Qed.
579 580
Lemma alter_app_l f l1 l2 i :
  i < length l1 → alter f i (l1 ++ l2) = alter f i l1 ++ l2.
581
Proof. revert i. induction l1; intros [|?] ?; f_equal/=; auto with lia. Qed.
582
Lemma alter_app_r f l1 l2 i :
583
  alter f (length l1 + i) (l1 ++ l2) = l1 ++ alter f i l2.
584
Proof. revert i. induction l1; intros [|?]; f_equal/=; auto. Qed.
585 586
Lemma alter_app_r_alt f l1 l2 i :
  length l1 ≤ i → alter f i (l1 ++ l2) = l1 ++ alter f (i - length l1) l2.
587 588 589 590
Proof.
  intros. assert (i = length l1 + (i - length l1)) as Hi by lia.
  rewrite Hi at 1. by apply alter_app_r.
Qed.
591
Lemma list_alter_id f l i : (∀ x, f x = x) → alter f i l = l.
592
Proof. intros ?. revert i. induction l; intros [|?]; f_equal/=; auto. Qed.
593 594
Lemma list_alter_ext f g l k i :
  (∀ x, l !! i = Some x → f x = g x) → l = k → alter f i l = alter g i k.
595
Proof. intros H ->. revert i H. induction k; intros [|?] ?; f_equal/=; auto. Qed.
596 597
Lemma list_alter_compose f g l i :
  alter (f ∘ g) i l = alter f i (alter g i l).
598
Proof. revert i. induction l; intros [|?]; f_equal/=; auto. Qed.
599 600
Lemma list_alter_commute f g l i j :
  i ≠ j → alter f i (alter g j l) = alter g j (alter f i l).
601
Proof. revert i j. induction l; intros [|?][|?] ?; f_equal/=; auto with lia. Qed.
602 603
Lemma insert_app_l l1 l2 i x :
  i < length l1 → <[i:=x]>(l1 ++ l2) = <[i:=x]>l1 ++ l2.
604
Proof. revert i. induction l1; intros [|?] ?; f_equal/=; auto with lia. Qed.
605
Lemma insert_app_r l1 l2 i x : <[length l1+i:=x]>(l1 ++ l2) = l1 ++ <[i:=x]>l2.
606
Proof. revert i. induction l1; intros [|?]; f_equal/=; auto. Qed.
607 608
Lemma insert_app_r_alt l1 l2 i x :
  length l1 ≤ i → <[i:=x]>(l1 ++ l2) = l1 ++ <[i - length l1:=x]>l2.
609 610 611 612
Proof.
  intros. assert (i = length l1 + (i - length l1)) as Hi by lia.
  rewrite Hi at 1. by apply insert_app_r.
Qed.
613
Lemma delete_middle l1 l2 x : delete (length l1) (l1 ++ x :: l2) = l1 ++ l2.
614
Proof. induction l1; f_equal/=; auto. Qed.
615

616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652
Lemma inserts_length l i k : length (list_inserts i k l) = length l.
Proof.
  revert i. induction k; intros ?; csimpl; rewrite ?insert_length; auto.
Qed.
Lemma list_lookup_inserts l i k j :
  i ≤ j < i + length k → j < length l →
  list_inserts i k l !! j = k !! (j - i).
Proof.
  revert i j. induction k as [|y k IH]; csimpl; intros i j ??; [lia|].
  destruct (decide (i = j)) as [->|].
  { by rewrite list_lookup_insert, Nat.sub_diag
      by (rewrite inserts_length; lia). }
  rewrite list_lookup_insert_ne, IH by lia.
  by replace (j - i) with (S (j - S i)) by lia.
Qed.
Lemma list_lookup_inserts_lt l i k j :
  j < i → list_inserts i k l !! j = l !! j.
Proof.
  revert i j. induction k; intros i j ?; csimpl;
    rewrite ?list_lookup_insert_ne by lia; auto with lia.
Qed.
Lemma list_lookup_inserts_ge l i k j :
  i + length k ≤ j → list_inserts i k l !! j = l !! j.
Proof.
  revert i j. induction k; csimpl; intros i j ?;
    rewrite ?list_lookup_insert_ne by lia; auto with lia.
Qed.
Lemma list_lookup_inserts_Some l i k j y :
  list_inserts i k l !! j = Some y ↔
    (j < i ∨ i + length k ≤ j) ∧ l !! j = Some y ∨
    i ≤ j < i + length k ∧ j < length l ∧ k !! (j - i) = Some y.
Proof.
  destruct (decide (j < i)).
  { rewrite list_lookup_inserts_lt by done; intuition lia. }
  destruct (decide (i + length k ≤ j)).
  { rewrite list_lookup_inserts_ge by done; intuition lia. }
  split.
653
  - intros Hy. assert (j < length l).
654 655
    { rewrite <-(inserts_length l i k); eauto using lookup_lt_Some. }
    rewrite list_lookup_inserts in Hy by lia. intuition lia.
656
  - intuition. by rewrite list_lookup_inserts by lia.
657 658 659 660 661 662 663 664
Qed.
Lemma list_insert_inserts_lt l i j x k :
  i < j → <[i:=x]>(list_inserts j k l) = list_inserts j k (<[i:=x]>l).
Proof.
  revert i j. induction k; intros i j ?; simpl;
    rewrite 1?list_insert_commute by lia; auto with f_equal.
Qed.

665
(** ** Properties of the [elem_of] predicate *)
666
Lemma not_elem_of_nil x : x ∉ [].
667
Proof. by inversion 1. Qed.
668
Lemma elem_of_nil x : x ∈ [] ↔ False.
669
Proof. intuition. by destruct (not_elem_of_nil x). Qed.
670
Lemma elem_of_nil_inv l : (∀ x, x ∉ l) → l = [].
671
Proof. destruct l. done. by edestruct 1; constructor. Qed.
672 673
Lemma elem_of_not_nil x l : x ∈ l → l ≠ [].
Proof. intros ? ->. by apply (elem_of_nil x). Qed.
674
Lemma elem_of_cons l x y : x ∈ y :: l ↔ x = y ∨ x ∈ l.
Robbert Krebbers's avatar
Robbert Krebbers committed
675
Proof. by split; [inversion 1; subst|intros [->|?]]; constructor. Qed.
676
Lemma not_elem_of_cons l x y : x ∉ y :: l ↔ x ≠ y ∧ x ∉ l.
Robbert Krebbers's avatar
Robbert Krebbers committed
677
Proof. rewrite elem_of_cons. tauto. Qed.
678
Lemma elem_of_app l1 l2 x : x ∈ l1 ++ l2 ↔ x ∈ l1 ∨ x ∈ l2.
679
Proof.
680
  induction l1.
681 682
  - split; [by right|]. intros [Hx|]; [|done]. by destruct (elem_of_nil x).
  - simpl. rewrite !elem_of_cons, IHl1. tauto.
683
Qed.
684
Lemma not_elem_of_app l1 l2 x : x ∉ l1 ++ l2 ↔ x ∉ l1 ∧ x ∉ l2.
Robbert Krebbers's avatar
Robbert Krebbers committed
685
Proof. rewrite elem_of_app. tauto. Qed.
686
Lemma elem_of_list_singleton x y : x ∈ [y] ↔ x = y.
687
Proof. rewrite elem_of_cons, elem_of_nil. tauto. Qed.
Robbert Krebbers's avatar
Robbert Krebbers committed
688
Global Instance elem_of_list_permutation_proper x : Proper ((≡ₚ) ==> iff) (x ∈).
689
Proof. induction 1; rewrite ?elem_of_nil, ?elem_of_cons; intuition. Qed.
690
Lemma elem_of_list_split l x : x ∈ l → ∃ l1 l2, l = l1 ++ x :: l2.
691
Proof.
692
  induction 1 as [x l|x y l ? [l1 [l2 ->]]]; [by eexists [], l|].
693
  by exists (y :: l1), l2.
694
Qed.
695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714 715 716
Lemma elem_of_list_split_l `{EqDecision A} l x :
  x ∈ l → ∃ l1 l2, l = l1 ++ x :: l2 ∧ x ∉ l1.
Proof.
  induction 1 as [x l|x y l ? IH].
  { exists [], l. rewrite elem_of_nil. naive_solver. }
  destruct (decide (x = y)) as [->|?].
  - exists [], l. rewrite elem_of_nil. naive_solver.
  - destruct IH as (l1 & l2 & -> & ?).
    exists (y :: l1), l2. rewrite elem_of_cons. naive_solver.
Qed.
Lemma elem_of_list_split_r `{EqDecision A} l x :
  x ∈ l → ∃ l1 l2, l = l1 ++ x :: l2 ∧ x ∉ l2.
Proof.
  induction l as [|y l IH] using rev_ind.
  { by rewrite elem_of_nil. }
  destruct (decide (x = y)) as [->|].
  - exists l, []. rewrite elem_of_nil. naive_solver.
  - rewrite elem_of_app, elem_of_list_singleton. intros [?| ->]; try done.
    destruct IH as (l1 & l2 & -> & ?); auto.
    exists l1, (l2 ++ [y]).
    rewrite elem_of_app, elem_of_list_singleton, <-(assoc_L (++)). naive_solver.
Qed.
717
Lemma elem_of_list_lookup_1 l x : x ∈ l → ∃ i, l !! i = Some x.
718
Proof.
719 720
  induction 1 as [|???? IH]; [by exists 0 |].
  destruct IH as [i ?]; auto. by exists (S i).
721
Qed.
722
Lemma elem_of_list_lookup_2 l i x : l !! i = Some x → x ∈ l.
723
Proof.
724
  revert i. induction l; intros [|i] ?; simplify_eq/=; constructor; eauto.
725
Qed.
726 727
Lemma elem_of_list_lookup l x : x ∈ l ↔ ∃ i, l !! i = Some x.
Proof. firstorder eauto using elem_of_list_lookup_1, elem_of_list_lookup_2. Qed.
728 729 730 731
Lemma elem_of_list_omap {B} (f : A → option B) l (y : B) :
  y ∈ omap f l ↔ ∃ x, x ∈ l ∧ f x = Some y.
Proof.
  split.
732
  - induction l as [|x l]; csimpl; repeat case_match; inversion 1; subst;
733
      setoid_rewrite elem_of_cons; naive_solver.
734
  - intros (x&Hx&?). by induction Hx; csimpl; repeat case_match;
735
      simplify_eq; try constructor; auto.
736
Qed.
737 738 739 740 741 742 743
Lemma list_elem_of_insert l i x : i < length l → x ∈ <[i:=x]>l.
Proof. intros. by eapply elem_of_list_lookup_2, list_lookup_insert. Qed.
Lemma nth_elem_of l i d : i < length l → nth i l d ∈ l.
Proof.
  intros; eapply elem_of_list_lookup_2.
  destruct (nth_lookup_or_length l i d); [done | by lia].
Qed.
744

745
(** ** Properties of the [NoDup] predicate *)
746 747
Lemma NoDup_nil : NoDup (@nil A) ↔ True.
Proof. split; constructor. Qed.
748
Lemma NoDup_cons x l : NoDup (x :: l) ↔ x ∉ l ∧ NoDup l.
749
Proof. split. by inversion 1. intros [??]. by constructor. Qed.
750
Lemma NoDup_cons_11 x l : NoDup (x :: l) → x ∉ l.
751
Proof. rewrite NoDup_cons. by intros [??]. Qed.
752
Lemma NoDup_cons_12 x l : NoDup (x :: l) → NoDup l.
753
Proof. rewrite NoDup_cons. by intros [??]. Qed.
754
Lemma NoDup_singleton x : NoDup [x].
755
Proof. constructor. apply not_elem_of_nil. constructor. Qed.
756
Lemma NoDup_app l k : NoDup (l ++ k) ↔ NoDup l ∧ (∀ x, x ∈ l → x ∉ k) ∧ NoDup k.
Robbert Krebbers's avatar
Robbert Krebbers committed
757
Proof.
758
  induction l; simpl.
759 760
  - rewrite NoDup_nil. setoid_rewrite elem_of_nil. naive_solver.
  - rewrite !NoDup_cons.
Robbert Krebbers's avatar
Robbert Krebbers committed
761
    setoid_rewrite elem_of_cons. setoid_rewrite elem_of_app. naive_solver.
Robbert Krebbers's avatar
Robbert Krebbers committed
762
Qed.
763
Global Instance NoDup_proper: Proper ((≡ₚ) ==> iff) (@NoDup A).
764 765
Proof.
  induction 1 as [|x l k Hlk IH | |].
766 767 768 769
  - by rewrite !NoDup_nil.
  - by rewrite !NoDup_cons, IH, Hlk.
  - rewrite !NoDup_cons, !elem_of_cons. intuition.
  - intuition.
770
Qed.
771 772
Lemma NoDup_lookup l i j x :
  NoDup l → l !! i = Some x → l !! j = Some x → i = j.
773 774
Proof.
  intros Hl. revert i j. induction Hl as [|x' l Hx Hl IH].
775 776
  { intros; simplify_eq. }
  intros [|i] [|j] ??; simplify_eq/=; eauto with f_equal;
777 778
    exfalso; eauto using elem_of_list_lookup_2.
Qed.
779 780
Lemma NoDup_alt l :
  NoDup l ↔ ∀ i j x, l !! i = Some x → l !! j = Some x → i = j.
781
Proof.
782 783
  split; eauto using NoDup_lookup.
  induction l as [|x l IH]; intros Hl; constructor.
784
  - rewrite elem_of_list_lookup. intros [i ?].
785
    by feed pose proof (Hl (S i) 0 x); auto.
786
  - apply IH. intros i j x' ??. by apply (inj S), (Hl (S i) (S j) x').
787
Qed.
Robbert Krebbers's avatar
Robbert Krebbers committed
788

789
Section no_dup_dec.
790
  Context `{!EqDecision A}.
791 792 793 794
  Global Instance NoDup_dec: ∀ l, Decision (NoDup l) :=
    fix NoDup_dec l :=
    match l return Decision (NoDup l) with
    | [] => left NoDup_nil_2
795
    | x :: l =>
796 797 798 799 800 801 802 803
      match decide_rel (∈) x l with
      | left Hin => right (λ H, NoDup_cons_11 _ _ H Hin)
      | right Hin =>
        match NoDup_dec l with
        | left H => left (NoDup_cons_2 _ _ Hin H)
        | right H => right (H ∘ NoDup_cons_12 _ _)
        end
      end
804
    end.
805
  Lemma elem_of_remove_dups l x : x ∈ remove_dups l ↔ x ∈ l.
806 807
  Proof.
    split; induction l; simpl; repeat case_decide;
808
      rewrite ?elem_of_cons; intuition (simplify_eq; auto).
809
  Qed.
810
  Lemma NoDup_remove_dups l : NoDup (remove_dups l).
811 812 813 814
  Proof.
    induction l; simpl; repeat case_decide; try constructor; auto.
    by rewrite elem_of_remove_dups.
  Qed.
815
End no_dup_dec.
816

817 818
(** ** Set operations on lists *)
Section list_set.
819 820 821 822 823 824 825 826 827 828 829 830 831 832 833 834 835 836 837 838 839 840
  Lemma elem_of_list_intersection_with f l k x :
    x ∈ list_intersection_with f l k ↔ ∃ x1 x2,
        x1 ∈ l ∧ x2 ∈ k ∧ f x1 x2 = Some x.
  Proof.
    split.
    - induction l as [|x1 l IH]; simpl; [by rewrite elem_of_nil|].
      intros Hx. setoid_rewrite elem_of_cons.
      cut ((∃ x2, x2 ∈ k ∧ f x1 x2 = Some x)
           ∨ x ∈ list_intersection_with f l k); [naive_solver|].
      clear IH. revert Hx. generalize (list_intersection_with f l k).
      induction k; simpl; [by auto|].
      case_match; setoid_rewrite elem_of_cons; naive_solver.
    - intros (x1&x2&Hx1&Hx2&Hx). induction Hx1 as [x1|x1 ? l ? IH]; simpl.
      + generalize (list_intersection_with f l k).
        induction Hx2; simpl; [by rewrite Hx; left |].
        case_match; simpl; try setoid_rewrite elem_of_cons; auto.
      + generalize (IH Hx). clear Hx IH Hx2.
        generalize (list_intersection_with f l k).
        induction k; simpl; intros; [done|].
        case_match; simpl; rewrite ?elem_of_cons; auto.
  Qed.

841
  Context `{!EqDecision A}.
842 843 844 845 846 847 848 849
  Lemma elem_of_list_difference l k x : x ∈ list_difference l k ↔ x ∈ l ∧ x ∉ k.
  Proof.
    split; induction l; simpl; try case_decide;
      rewrite ?elem_of_nil, ?elem_of_cons; intuition congruence.
  Qed.
  Lemma NoDup_list_difference l k : NoDup l → NoDup (list_difference l k).
  Proof.
    induction 1; simpl; try case_decide.
850 851 852
    - constructor.
    - done.
    - constructor. rewrite elem_of_list_difference; intuition. done.
853 854 855 856 857 858 859 860 861
  Qed.
  Lemma elem_of_list_union l k x : x ∈ list_union l k ↔ x ∈ l ∨ x ∈ k.
  Proof.
    unfold list_union. rewrite elem_of_app, elem_of_list_difference.
    intuition. case (decide (x ∈ k)); intuition.
  Qed.
  Lemma NoDup_list_union l k : NoDup l → NoDup k → NoDup (list_union l k).
  Proof.
    intros. apply NoDup_app. repeat split.
862 863 864
    - by apply NoDup_list_difference.
    - intro. rewrite elem_of_list_difference. intuition.
    - done.
865 866 867 868 869 870 871 872 873 874
  Qed.
  Lemma elem_of_list_intersection l k x :
    x ∈ list_intersection l k ↔ x ∈ l ∧ x ∈ k.
  Proof.
    split; induction l; simpl; repeat case_decide;
      rewrite ?elem_of_nil, ?elem_of_cons; intuition congruence.
  Qed.
  Lemma NoDup_list_intersection l k : NoDup l → NoDup (list_intersection l k).
  Proof.
    induction 1; simpl; try case_decide.
875 876 877
    - constructor.
    - constructor. rewrite elem_of_list_intersection; intuition. done.
    - done.
878 879 880
  Qed.
End list_set.

881 882 883
(** ** Properties of the [find] function *)
Section find.
  Context (P : A → Prop) `{∀ x, Decision (P x)}.
884 885
  Lemma list_find_Some l i x :
    list_find P l = Some (i,x) → l !! i = Some x ∧ P x.
886
  Proof.
887 888 889
    revert i; induction l; intros [] ?; repeat first
      [ match goal with x : prod _ _ |- _ => destruct x end
      | simplify_option_eq ]; eauto.
890
  Qed.
891 892 893 894 895 896 897
  Lemma list_find_None l :
    list_find P l = None → Forall (λ x, ¬ P x) l.
  Proof.
    induction l as [|? l IHl]; [eauto|]. simpl. case_decide; [done|].
    intros. constructor; [done|]. apply IHl.
    by destruct (list_find P l).
  Qed.
898
  Lemma list_find_elem_of l x : x ∈ l → P x → is_Some (list_find P l).
899
  Proof.
900
    induction 1 as [|x y l ? IH]; intros; simplify_option_eq; eauto.
901
    by destruct IH as [[i x'] ->]; [|exists (S i, x')].
902 903 904
  Qed.
End find.

905
(** ** Properties of the [reverse] function *)
906
Lemma reverse_nil : reverse [] =@{list A} [].
907
Proof. done. Qed.
908
Lemma reverse_singleton x : reverse [x] = [x].
909
Proof. done. Qed.
910
Lemma reverse_cons l x : reverse (x :: l) = reverse l ++ [x].
911
Proof. unfold reverse. by rewrite <-!rev_alt. Qed.
912
Lemma reverse_snoc l x : reverse (l ++ [x]) = x :: reverse l.
913
Proof. unfold reverse. by rewrite <-!rev_alt, rev_unit. Qed.
914
Lemma reverse_app l1 l2 : reverse (l1 ++ l2) = reverse l2 ++ reverse l1.
915
Proof. unfold reverse. rewrite <-!rev_alt. apply rev_app_distr. Qed.
916
Lemma reverse_length l : length (reverse l) = length l.
917
Proof. unfold reverse. rewrite <-!rev_alt. apply rev_length. Qed.
918
Lemma reverse_involutive l : reverse (reverse l) = l.
919
Proof. unfold reverse. rewrite <-!rev_alt. apply rev_involutive. Qed.
920 921 922 923 924 925 926 927 928 929
Lemma elem_of_reverse_2 x l : x ∈ l → x ∈ reverse l.
Proof.
  induction 1; rewrite reverse_cons, elem_of_app,
    ?elem_of_list_singleton; intuition.
Qed.
Lemma elem_of_reverse x l : x ∈ reverse l ↔ x ∈ l.
Proof.
  split; auto using elem_of_reverse_2.
  intros. rewrite <-(reverse_involutive l). by apply elem_of_reverse_2.
Qed.
930
Global Instance: Inj (=) (=) (@reverse A).
931 932 933 934
Proof.
  intros l1 l2 Hl.
  by rewrite <-(reverse_involutive l1), <-(reverse_involutive l2), Hl.
Qed.
935 936 937 938 939 940 941 942
Lemma sum_list_with_app (f : A → nat) l k :
  sum_list_with f (l ++ k) = sum_list_with f l + sum_list_with f k.
Proof. induction l; simpl; lia. Qed.
Lemma sum_list_with_reverse (f : A → nat) l :
  sum_list_with f (reverse l) = sum_list_with f l.
Proof.
  induction l; simpl; rewrite ?reverse_cons, ?sum_list_with_app; simpl; lia.
Qed.
943

944 945 946
(** ** Properties of the [last] function *)
Lemma last_snoc x l : last (l ++ [x]) = Some x.
Proof. induction l as [|? []]; simpl; auto. Qed.
947 948 949 950
Lemma last_reverse l : last (reverse l) = head l.
Proof. by destruct l as [|x l]; rewrite ?reverse_cons, ?last_snoc. Qed.
Lemma head_reverse l : head (reverse l) = last l.
Proof. by rewrite <-last_reverse, reverse_involutive. Qed.
951

952 953 954 955 956
(** ** Properties of the [take] function *)
Definition take_drop i l : take i l ++ drop i l = l := firstn_skipn i l.
Lemma take_drop_middle l i x :
  l !! i = Some x → take i l ++ x :: drop (S i) l = l.
Proof.
957
  revert i x. induction l; intros [|?] ??; simplify_eq/=; f_equal; auto.
958
Qed.
Robbert Krebbers's avatar